home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Extravaganza - Disc 4
/
Shareware Extravaganza - Over 25,000 Programs (The Ultimate Shareware Company)(Disc 4 of 4)(1993).iso
/
cad
/
pspice3.zip
/
MNOM.LIB
< prev
next >
Wrap
Text File
|
1986-09-04
|
3KB
|
78 lines
* Library of MOSFET model parameters (for "power" MOSFET devices)
*
* This is a reduced version of MicroSim's power MOSFET model library.
* You are welcome to make as many copies of it as you find convenient.
*
* Release date: January 15, 1986
*
* The parameters in this model library were derived from the data
* sheets for each part. The methods used were as follows:
* LEVEL Set to 3 (short-channel device).
* TOX Determined from gate ratings.
* L, LD, W, WD Assume L=2u. Calculate from input capacitance.
* XJ, NSUB Assume usual technology.
* IS, RD, RB Determined from "source-drain diode forward voltage"
* specification or curve (Idr vs. Vsd).
* RS Determine from Rds(on) specification.
* RDS Calculated from Idss specification or curves.
* VTO, UO, THETA Determined from "output characteristics" curve family
* (Ids vs. Vds, stepped Vgs).
* ETA, VMAX, CBS Set for null effect.
* CBD, PB, MJ Determined from "capacitance vs. Vds" curves.
* RG Calculate from rise/fall time specification or curves.
* CGSO, CGDO Determined from gate-charge, turn-on/off delay and
* rise time specifications.
*
* NOTE: when specifying the instance of a device in your circuit file:
*
* BE SURE to have the source and bulk nodes connected together, as this
* is the way the real device is constructed.
*
* DO NOT include values for L, W, AD, AS, PD, PS, NRD, or NDS.
* The PSpice default values for these parameters are taken into account
* in the library model statements. Of course, you should NOT reset
* the default values using the .OPTIONS statement, either.
*
* Example use: M17 15 23 7 7 IRF150
*
* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
*
* The "power" MOSFET device models benefit from relatively complete specifi-
* cation of static and dynamic characteristics by their manufacturers. The
* following effects are modeled:
* - DC transfer curves in forward operation,
* - gate drive characteristics and switching delay,
* - "on" resistance,
* - reverse-mode "body-diode" operation.
*
* The factors not modeled include:
* - maximum ratings (eg. high-voltage breakdown),
* - safe operating area (eg. power dissipation),
* - latch-up,
* - noise.
*
* For high-current switching applications, we advise that you include
* series inductance elements, for the source and drain, in your circuit file.
* In doing so, voltage spikes due to di/dt will be modeled. According to the
* 1985 International Rectifier databook, the following case styles have lead
* inductance values of:
* TO-204 (modified TO-3) source = 12.5nH drain = 5.0nH
* TO-220 source = 7.5nH drain = 3.5-4.5nH
* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
*
* IRF150, from 1985 Siliconix databook, pages 1-7,8 and 5-22,3
*
.MODEL IRF150 NMOS(LEVEL=3 TOX=.10U L=3.0U LD=.5U W=2.0 WD=0 XJ=1.2U
+ NSUB=4E14 IS=2.1E-14 RB=0 RD=.01 RS=.03 RDS=1E6 VTO=3.25
+ UO=550 THETA=.1 ETA=0 VMAX=1E6 CBS=1P CBD=4000P PB=.7 MJ=.5
+ RG=4.9 CGSO=1690P CGDO=365P CGBO=1P)
*
* IRF9130, from 1985 International Rectifier databook, pages D-187,92
*
.MODEL IRF9130 PMOS(LEVEL=3 TOX=.1U L=3.0U LD=.5U W=1.3 WD=0 XJ=1.2U
+ NSUB=4E14 IS=2.1E-14 RB=0 RD=.03 RS=.2 RDS=5E5 VTO=-3.7
+ UO=600 THETA=.1 ETA=0 VMAX=1E6 CBS=1P CBD=2000P PB=.7 MJ=.5
+ RG=5 CGSO=520P CGDO=180P CGBO=1P)
*
* End of library file